Value GROUP (\d+)
Value VERSION (\d+)
Value STATE (\w+)
Value VIRTUAL_IP (\S+)
Value ACTIVE_VIRTUAL_MAC (\S+)
Value LOCAL_VIRTUAL_MAC (\S+)
Value HELLO_TIME (\d+)
Value HOLD_TIME (\d+)
Value AUTHENTICATION (\w+)
Value PREEMPTION (\w+)
Value ACTIVE_ROUTER (\d+\.\d+\.\d+\.\d+|local)
Value ACTIVE_ROUTER_PRIORITY (\d+)
Value ACTIVE_ROUTER_MAC (\S+)
Value STANDBY_ROUTER (\d+\.\d+\.\d+\.\d+|local)
Value STANDBY_ROUTER_PRIORITY (\d+)
Value PRIORITY (\d+)
Value GROUP_NAME (\S+)

Start
  ^.*Group\s+${GROUP}\s+\(version\s+${VERSION}\)
  ^.*State\s+is\s+${STATE}
  ^.*Virtual\s+IP\s+address\s+is\s+${VIRTUAL_IP}
  ^.*Active\s+virtual\s+MAC\s+address\s+is\s+${ACTIVE_VIRTUAL_MAC}
  ^.*Local\s+virtual\s+MAC\s+address\s+is\s+${LOCAL_VIRTUAL_MAC}
  ^.*Hello\s+time\s+${HELLO_TIME}.*hold\s+time\s+${HOLD_TIME}
  ^.*Authentication\s+${AUTHENTICATION}
  ^.*Preemption\s+${PREEMPTION}
  ^.*Active\s+router\s+is\s+${ACTIVE_ROUTER}(,\s+priority\s+${ACTIVE_ROUTER_PRIORITY})?
  ^\s+MAC\s+address\s+is\s+${ACTIVE_ROUTER_MAC}
  ^.*Standby\s+router\s+is\s+${STANDBY_ROUTER}(,\s+priority\s+${STANDBY_ROUTER_PRIORITY})?
  ^.*Priority\s+${PRIORITY}
  ^.*Group\s+name\s+is\s+"${GROUP_NAME}" -> Record
  # Capture time-stamp if vty line has command time-stamping turned on
  ^Load\s+for\s+
  ^Time\s+source\s+is
