/* Script for -N: mix text and data on same page; don't align data */
OUTPUT_FORMAT(elf32-m68k)
OUTPUT_ARCH(m68k)
SEARCH_DIR("/usr/pkg/cross/i386-linux/lib");
SECTIONS
{
  .text   0x20000 : {
     start = DEFINED(_START) ? _START : DEFINED(_start) ? _start : .;
     PROVIDE(__text = .);
    *(.text);
    *(code);
    *(const);
    *(strings);
    *(pSOS);
    *(pROBE);
    *(pNA);
    *(pHILE);
    *(pREPC);
    *(pRPC);
     ___CTOR_LIST__ = .;
     LONG((___CTOR_END__ - ___CTOR_LIST__) / 4 - 2)
     *(.ctors)
     LONG(0);
     ___CTOR_END__ = .;
     ___DTOR_LIST__ = .;
     LONG((___DTOR_END__ - ___DTOR_LIST__) / 4 - 2);
     *(.dtors);
     LONG(0);
     ___DTOR_END__ = .;
     PROVIDE(__etext = .);
     PROVIDE(_etext = .);
  }
  .data   :  AT(ADDR(.text) + SIZEOF(.text)) {
     PROVIDE(__data = .);
    *(.data);
    *(vars);
     PROVIDE(__edata = .);
     PROVIDE(_edata = .);
  }
  .bss   :
  {
     PROVIDE(__bss = .);
    *(.bss);
    *(zerovars);
    *(COMMON);
     PROVIDE(__ebss = .);
     PROVIDE(__end = .);
     PROVIDE(_end = .);
     PROVIDE(_FreeMemStart = .);
  }
  .stab 0 (NOLOAD) :
  {
    *(.stab);
  }
  .stabstr 0 (NOLOAD) :
  {
    *(.stabstr);
  }
}
